warp_scan.cuh

Go to the documentation of this file.

/******************************************************************************
 * Copyright (c) 2011, Duane Merrill.  All rights reserved.
 * Copyright (c) 2011-2018, NVIDIA CORPORATION.  All rights reserved.
 * 
 * Redistribution and use in source and binary forms, with or without
 * modification, are permitted provided that the following conditions are met:
 *     * Redistributions of source code must retain the above copyright
 *       notice, this list of conditions and the following disclaimer.
 *     * Redistributions in binary form must reproduce the above copyright
 *       notice, this list of conditions and the following disclaimer in the
 *       documentation and/or other materials provided with the distribution.
 *     * Neither the name of the NVIDIA CORPORATION nor the
 *       names of its contributors may be used to endorse or promote products
 *       derived from this software without specific prior written permission.
 * 
 * THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS" AND
 * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED
 * WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE
 * DISCLAIMED. IN NO EVENT SHALL NVIDIA CORPORATION BE LIABLE FOR ANY
 * DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES
 * (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
 * LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND
 * ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
 * (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
 * SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
 *
 ******************************************************************************/

#pragma once

#include "specializations/warp_scan_shfl.cuh"
#include "specializations/warp_scan_smem.cuh"
#include "../thread/thread_operators.cuh"
#include "../util_arch.cuh"
#include "../util_type.cuh"
#include "../util_namespace.cuh"

CUB_NS_PREFIX

namespace cub {

template <
    typename    T,
    int         LOGICAL_WARP_THREADS    = CUB_PTX_WARP_THREADS,
    int         PTX_ARCH                = CUB_PTX_ARCH>
class WarpScan
{
private:

    /******************************************************************************
     * Constants and type definitions
     ******************************************************************************/

    enum
    {
        IS_ARCH_WARP = (LOGICAL_WARP_THREADS == CUB_WARP_THREADS(PTX_ARCH)),

        IS_POW_OF_TWO = ((LOGICAL_WARP_THREADS & (LOGICAL_WARP_THREADS - 1)) == 0),

        IS_INTEGER = ((Traits<T>::CATEGORY == SIGNED_INTEGER) || (Traits<T>::CATEGORY == UNSIGNED_INTEGER))
    };

    typedef typename If<(PTX_ARCH >= 300) && (IS_POW_OF_TWO),
        WarpScanShfl<T, LOGICAL_WARP_THREADS, PTX_ARCH>,
        WarpScanSmem<T, LOGICAL_WARP_THREADS, PTX_ARCH> >::Type InternalWarpScan;

    typedef typename InternalWarpScan::TempStorage _TempStorage;


    /******************************************************************************
     * Thread fields
     ******************************************************************************/

    _TempStorage    &temp_storage;
    unsigned int    lane_id;



    /******************************************************************************
     * Public types
     ******************************************************************************/

public:

    struct TempStorage : Uninitialized<_TempStorage> {};


    /******************************************************************/

    __device__ __forceinline__ WarpScan(
        TempStorage &temp_storage)             
    :
        temp_storage(temp_storage.Alias()),
        lane_id(IS_ARCH_WARP ?
            LaneId() :
            LaneId() % LOGICAL_WARP_THREADS)
    {}


    /******************************************************************/


    __device__ __forceinline__ void InclusiveSum(
        T               input,              
        T               &inclusive_output)  
    {
        InclusiveScan(input, inclusive_output, cub::Sum());
    }


    __device__ __forceinline__ void InclusiveSum(
        T               input,              
        T               &inclusive_output,  
        T               &warp_aggregate)    
    {
        InclusiveScan(input, inclusive_output, cub::Sum(), warp_aggregate);
    }


    /******************************************************************/


    __device__ __forceinline__ void ExclusiveSum(
        T               input,              
        T               &exclusive_output)  
    {
        T initial_value = 0;
        ExclusiveScan(input, exclusive_output, initial_value, cub::Sum());
    }


    __device__ __forceinline__ void ExclusiveSum(
        T               input,              
        T               &exclusive_output,  
        T               &warp_aggregate)    
    {
        T initial_value = 0;
        ExclusiveScan(input, exclusive_output, initial_value, cub::Sum(), warp_aggregate);
    }


    /******************************************************************/

    template <typename ScanOp>
    __device__ __forceinline__ void InclusiveScan(
        T               input,              
        T               &inclusive_output,  
        ScanOp          scan_op)            
    {
        InternalWarpScan(temp_storage).InclusiveScan(input, inclusive_output, scan_op);
    }


    template <typename ScanOp>
    __device__ __forceinline__ void InclusiveScan(
        T               input,              
        T               &inclusive_output,  
        ScanOp          scan_op,            
        T               &warp_aggregate)    
    {
        InternalWarpScan(temp_storage).InclusiveScan(input, inclusive_output, scan_op, warp_aggregate);
    }


    /******************************************************************/

    template <typename ScanOp>
    __device__ __forceinline__ void ExclusiveScan(
        T               input,              
        T               &exclusive_output,  
        ScanOp          scan_op)            
    {
        InternalWarpScan internal(temp_storage);

        T inclusive_output;
        internal.InclusiveScan(input, inclusive_output, scan_op);

        internal.Update(
            input,
            inclusive_output,
            exclusive_output,
            scan_op,
            Int2Type<IS_INTEGER>());
    }


    template <typename ScanOp>
    __device__ __forceinline__ void ExclusiveScan(
        T               input,              
        T               &exclusive_output,  
        T               initial_value,      
        ScanOp          scan_op)            
    {
        InternalWarpScan internal(temp_storage);

        T inclusive_output;
        internal.InclusiveScan(input, inclusive_output, scan_op);

        internal.Update(
            input,
            inclusive_output,
            exclusive_output,
            scan_op,
            initial_value,
            Int2Type<IS_INTEGER>());
    }


    template <typename ScanOp>
    __device__ __forceinline__ void ExclusiveScan(
        T               input,              
        T               &exclusive_output,   
        ScanOp          scan_op,            
        T               &warp_aggregate)    
    {
        InternalWarpScan internal(temp_storage);

        T inclusive_output;
        internal.InclusiveScan(input, inclusive_output, scan_op);

        internal.Update(
            input,
            inclusive_output,
            exclusive_output,
            warp_aggregate,
            scan_op,
            Int2Type<IS_INTEGER>());
    }


    template <typename ScanOp>
    __device__ __forceinline__ void ExclusiveScan(
        T               input,              
        T               &exclusive_output,  
        T               initial_value,      
        ScanOp          scan_op,            
        T               &warp_aggregate)    
    {
        InternalWarpScan internal(temp_storage);

        T inclusive_output;
        internal.InclusiveScan(input, inclusive_output, scan_op);

        internal.Update(
            input,
            inclusive_output,
            exclusive_output,
            warp_aggregate,
            scan_op,
            initial_value,
            Int2Type<IS_INTEGER>());
    }


    /******************************************************************/


    template <typename ScanOp>
    __device__ __forceinline__ void Scan(
        T               input,              
        T               &inclusive_output,  
        T               &exclusive_output,  
        ScanOp          scan_op)            
    {
        InternalWarpScan internal(temp_storage);

        internal.InclusiveScan(input, inclusive_output, scan_op);

        internal.Update(
            input,
            inclusive_output,
            exclusive_output,
            scan_op,
            Int2Type<IS_INTEGER>());
    }


    template <typename ScanOp>
    __device__ __forceinline__ void Scan(
        T               input,              
        T               &inclusive_output,  
        T               &exclusive_output,  
        T               initial_value,      
        ScanOp          scan_op)            
    {
        InternalWarpScan internal(temp_storage);

        internal.InclusiveScan(input, inclusive_output, scan_op);

        internal.Update(
            input,
            inclusive_output,
            exclusive_output,
            scan_op,
            initial_value,
            Int2Type<IS_INTEGER>());
    }



    /******************************************************************/

    __device__ __forceinline__ T Broadcast(
        T               input,              
        unsigned int    src_lane)           
    {
        return InternalWarpScan(temp_storage).Broadcast(input, src_lane);
    }


};
       // end group WarpModule

}               // CUB namespace
CUB_NS_POSTFIX  // Optional outer namespace(s)