thread_scan.cuh

Go to the documentation of this file.

/******************************************************************************
 * Copyright (c) 2011, Duane Merrill.  All rights reserved.
 * Copyright (c) 2011-2018, NVIDIA CORPORATION.  All rights reserved.
 * 
 * Redistribution and use in source and binary forms, with or without
 * modification, are permitted provided that the following conditions are met:
 *     * Redistributions of source code must retain the above copyright
 *       notice, this list of conditions and the following disclaimer.
 *     * Redistributions in binary form must reproduce the above copyright
 *       notice, this list of conditions and the following disclaimer in the
 *       documentation and/or other materials provided with the distribution.
 *     * Neither the name of the NVIDIA CORPORATION nor the
 *       names of its contributors may be used to endorse or promote products
 *       derived from this software without specific prior written permission.
 * 
 * THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS" AND
 * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED
 * WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE
 * DISCLAIMED. IN NO EVENT SHALL NVIDIA CORPORATION BE LIABLE FOR ANY
 * DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES
 * (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
 * LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND
 * ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
 * (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
 * SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
 *
 ******************************************************************************/

#pragma once

#include "../thread/thread_operators.cuh"
#include "../util_namespace.cuh"

CUB_NS_PREFIX

namespace cub {

namespace internal {


template <
    int         LENGTH,
    typename    T,
    typename    ScanOp>
__device__ __forceinline__ T ThreadScanExclusive(
    T                   inclusive,
    T                   exclusive,
    T                   *input,                 
    T                   *output,                
    ScanOp              scan_op,                
    Int2Type<LENGTH>    /*length*/)
{
    #pragma unroll
    for (int i = 0; i < LENGTH; ++i)
    {
        inclusive = scan_op(exclusive, input[i]);
        output[i] = exclusive;
        exclusive = inclusive;
    }

    return inclusive;
}



template <
    int         LENGTH,
    typename    T,
    typename    ScanOp>
__device__ __forceinline__ T ThreadScanExclusive(
    T           *input,                 
    T           *output,                
    ScanOp      scan_op,                
    T           prefix,                 
    bool        apply_prefix = true)    
{
    T inclusive = input[0];
    if (apply_prefix)
    {
        inclusive = scan_op(prefix, inclusive);
    }
    output[0] = prefix;
    T exclusive = inclusive;

    return ThreadScanExclusive(inclusive, exclusive, input + 1, output + 1, scan_op, Int2Type<LENGTH - 1>());
}


template <
    int         LENGTH,
    typename    T,
    typename    ScanOp>
__device__ __forceinline__ T ThreadScanExclusive(
    T           (&input)[LENGTH],       
    T           (&output)[LENGTH],      
    ScanOp      scan_op,                
    T           prefix,                 
    bool        apply_prefix = true)    
{
    return ThreadScanExclusive<LENGTH>((T*) input, (T*) output, scan_op, prefix, apply_prefix);
}









template <
    int         LENGTH,
    typename    T,
    typename    ScanOp>
__device__ __forceinline__ T ThreadScanInclusive(
    T                   inclusive,
    T                   *input,                 
    T                   *output,                
    ScanOp              scan_op,                
    Int2Type<LENGTH>    /*length*/)
{
    #pragma unroll
    for (int i = 0; i < LENGTH; ++i)
    {
        inclusive = scan_op(inclusive, input[i]);
        output[i] = inclusive;
    }

    return inclusive;
}


template <
    int         LENGTH,
    typename    T,
    typename    ScanOp>
__device__ __forceinline__ T ThreadScanInclusive(
    T           *input,                 
    T           *output,                
    ScanOp      scan_op)                
{
    T inclusive = input[0];
    output[0] = inclusive;

    // Continue scan
    return ThreadScanInclusive(inclusive, input + 1, output + 1, scan_op, Int2Type<LENGTH - 1>());
}


template <
    int         LENGTH,
    typename    T,
    typename    ScanOp>
__device__ __forceinline__ T ThreadScanInclusive(
    T           (&input)[LENGTH],       
    T           (&output)[LENGTH],      
    ScanOp      scan_op)                
{
    return ThreadScanInclusive<LENGTH>((T*) input, (T*) output, scan_op);
}


template <
    int         LENGTH,
    typename    T,
    typename    ScanOp>
__device__ __forceinline__ T ThreadScanInclusive(
    T           *input,                 
    T           *output,                
    ScanOp      scan_op,                
    T           prefix,                 
    bool        apply_prefix = true)    
{
    T inclusive = input[0];
    if (apply_prefix)
    {
        inclusive = scan_op(prefix, inclusive);
    }
    output[0] = inclusive;

    // Continue scan
    return ThreadScanInclusive(inclusive, input + 1, output + 1, scan_op, Int2Type<LENGTH - 1>());
}


template <
    int         LENGTH,
    typename    T,
    typename    ScanOp>
__device__ __forceinline__ T ThreadScanInclusive(
    T           (&input)[LENGTH],       
    T           (&output)[LENGTH],      
    ScanOp      scan_op,                
    T           prefix,                 
    bool        apply_prefix = true)    
{
    return ThreadScanInclusive<LENGTH>((T*) input, (T*) output, scan_op, prefix, apply_prefix);
}


       // end group UtilModule


}               // internal namespace
}               // CUB namespace
CUB_NS_POSTFIX  // Optional outer namespace(s)