block_reduce_raking_commutative_only.cuh

Go to the documentation of this file.

/******************************************************************************
 * Copyright (c) 2011, Duane Merrill.  All rights reserved.
 * Copyright (c) 2011-2018, NVIDIA CORPORATION.  All rights reserved.
 * 
 * Redistribution and use in source and binary forms, with or without
 * modification, are permitted provided that the following conditions are met:
 *     * Redistributions of source code must retain the above copyright
 *       notice, this list of conditions and the following disclaimer.
 *     * Redistributions in binary form must reproduce the above copyright
 *       notice, this list of conditions and the following disclaimer in the
 *       documentation and/or other materials provided with the distribution.
 *     * Neither the name of the NVIDIA CORPORATION nor the
 *       names of its contributors may be used to endorse or promote products
 *       derived from this software without specific prior written permission.
 * 
 * THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS" AND
 * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED
 * WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE
 * DISCLAIMED. IN NO EVENT SHALL NVIDIA CORPORATION BE LIABLE FOR ANY
 * DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES
 * (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
 * LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND
 * ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
 * (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
 * SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
 *
 ******************************************************************************/
 
#pragma once
 
#include "block_reduce_raking.cuh"
#include "../../warp/warp_reduce.cuh"
#include "../../thread/thread_reduce.cuh"
#include "../../util_ptx.cuh"
#include "../../util_namespace.cuh"
 
CUB_NS_PREFIX
 
namespace cub {
 
 
template <
    typename    T,              
    int         BLOCK_DIM_X,    
    int         BLOCK_DIM_Y,    
    int         BLOCK_DIM_Z,    
    int         PTX_ARCH>       
struct BlockReduceRakingCommutativeOnly
{
    enum
    {
        BLOCK_THREADS = BLOCK_DIM_X * BLOCK_DIM_Y * BLOCK_DIM_Z,
    };
 
    // The fall-back implementation to use when BLOCK_THREADS is not a multiple of the warp size or not all threads have valid values
    typedef BlockReduceRaking<T, BLOCK_DIM_X, BLOCK_DIM_Y, BLOCK_DIM_Z, PTX_ARCH> FallBack;
 
    enum
    {
        WARP_THREADS = CUB_WARP_THREADS(PTX_ARCH),
 
        USE_FALLBACK = ((BLOCK_THREADS % WARP_THREADS != 0) || (BLOCK_THREADS <= WARP_THREADS)),
 
        RAKING_THREADS = WARP_THREADS,
 
        SHARING_THREADS = CUB_MAX(1, BLOCK_THREADS - RAKING_THREADS),
 
        SEGMENT_LENGTH = SHARING_THREADS / WARP_THREADS,
    };
 
    typedef WarpReduce<T, RAKING_THREADS, PTX_ARCH> WarpReduce;
 
    typedef BlockRakingLayout<T, SHARING_THREADS, PTX_ARCH> BlockRakingLayout;
 
    union _TempStorage
    {
        struct
        {
            typename WarpReduce::TempStorage        warp_storage;        
            typename BlockRakingLayout::TempStorage raking_grid;         
        };
        typename FallBack::TempStorage              fallback_storage;    
    };
 
 
    struct TempStorage : Uninitialized<_TempStorage> {};
 
 
    // Thread fields
    _TempStorage &temp_storage;
    unsigned int linear_tid;
 
 
    __device__ __forceinline__ BlockReduceRakingCommutativeOnly(
        TempStorage &temp_storage)
    :
        temp_storage(temp_storage.Alias()),
        linear_tid(RowMajorTid(BLOCK_DIM_X, BLOCK_DIM_Y, BLOCK_DIM_Z))
    {}
 
 
    template <bool FULL_TILE>
    __device__ __forceinline__ T Sum(
        T                   partial,            
        int                 num_valid)          
    {
        if (USE_FALLBACK || !FULL_TILE)
        {
            return FallBack(temp_storage.fallback_storage).template Sum<FULL_TILE>(partial, num_valid);
        }
        else
        {
            // Place partial into shared memory grid
            if (linear_tid >= RAKING_THREADS)
                *BlockRakingLayout::PlacementPtr(temp_storage.raking_grid, linear_tid - RAKING_THREADS) = partial;
 
            CTA_SYNC();
 
            // Reduce parallelism to one warp
            if (linear_tid < RAKING_THREADS)
            {
                // Raking reduction in grid
                T *raking_segment = BlockRakingLayout::RakingPtr(temp_storage.raking_grid, linear_tid);
                partial = internal::ThreadReduce<SEGMENT_LENGTH>(raking_segment, cub::Sum(), partial);
 
                // Warpscan
                partial = WarpReduce(temp_storage.warp_storage).Sum(partial);
            }
        }
 
        return partial;
    }
 
 
    template <
        bool                FULL_TILE,
        typename            ReductionOp>
    __device__ __forceinline__ T Reduce(
        T                   partial,            
        int                 num_valid,          
        ReductionOp         reduction_op)       
    {
        if (USE_FALLBACK || !FULL_TILE)
        {
            return FallBack(temp_storage.fallback_storage).template Reduce<FULL_TILE>(partial, num_valid, reduction_op);
        }
        else
        {
            // Place partial into shared memory grid
            if (linear_tid >= RAKING_THREADS)
                *BlockRakingLayout::PlacementPtr(temp_storage.raking_grid, linear_tid - RAKING_THREADS) = partial;
 
            CTA_SYNC();
 
            // Reduce parallelism to one warp
            if (linear_tid < RAKING_THREADS)
            {
                // Raking reduction in grid
                T *raking_segment = BlockRakingLayout::RakingPtr(temp_storage.raking_grid, linear_tid);
                partial = internal::ThreadReduce<SEGMENT_LENGTH>(raking_segment, reduction_op, partial);
 
                // Warpscan
                partial = WarpReduce(temp_storage.warp_storage).Reduce(partial, reduction_op);
            }
        }
 
        return partial;
    }
 
};
 
}               // CUB namespace
CUB_NS_POSTFIX  // Optional outer namespace(s)