arg_index_input_iterator.cuh

Go to the documentation of this file.

/******************************************************************************
 * Copyright (c) 2011, Duane Merrill.  All rights reserved.
 * Copyright (c) 2011-2018, NVIDIA CORPORATION.  All rights reserved.
 * 
 * Redistribution and use in source and binary forms, with or without
 * modification, are permitted provided that the following conditions are met:
 *     * Redistributions of source code must retain the above copyright
 *       notice, this list of conditions and the following disclaimer.
 *     * Redistributions in binary form must reproduce the above copyright
 *       notice, this list of conditions and the following disclaimer in the
 *       documentation and/or other materials provided with the distribution.
 *     * Neither the name of the NVIDIA CORPORATION nor the
 *       names of its contributors may be used to endorse or promote products
 *       derived from this software without specific prior written permission.
 * 
 * THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS" AND
 * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED
 * WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE
 * DISCLAIMED. IN NO EVENT SHALL NVIDIA CORPORATION BE LIABLE FOR ANY
 * DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES
 * (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
 * LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND
 * ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
 * (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
 * SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
 *
 ******************************************************************************/

#pragma once

#include <iterator>
#include <iostream>

#include "../thread/thread_load.cuh"
#include "../thread/thread_store.cuh"
#include "../util_device.cuh"
#include "../util_namespace.cuh"

#include <thrust/version.h>

#if (THRUST_VERSION >= 100700)
    // This iterator is compatible with Thrust API 1.7 and newer
    #include <thrust/iterator/iterator_facade.h>
    #include <thrust/iterator/iterator_traits.h>
#endif // THRUST_VERSION

CUB_NS_PREFIX

namespace cub {

template <
    typename    InputIteratorT,
    typename    OffsetT             = ptrdiff_t,
    typename    OutputValueT        = typename std::iterator_traits<InputIteratorT>::value_type>
class ArgIndexInputIterator
{
public:

    // Required iterator traits
    typedef ArgIndexInputIterator                       self_type;              
    typedef OffsetT                                     difference_type;        
    typedef KeyValuePair<difference_type, OutputValueT> value_type;             
    typedef value_type*                                 pointer;                
    typedef value_type                                  reference;              

#if (THRUST_VERSION >= 100700)
    // Use Thrust's iterator categories so we can use these iterators in Thrust 1.7 (or newer) methods
    typedef typename thrust::detail::iterator_facade_category<
        thrust::any_system_tag,
        thrust::random_access_traversal_tag,
        value_type,
        reference
      >::type iterator_category;                                        
#else
    typedef std::random_access_iterator_tag     iterator_category;      
#endif  // THRUST_VERSION

private:

    InputIteratorT  itr;
    difference_type offset;

public:

    __host__ __device__ __forceinline__ ArgIndexInputIterator(
        InputIteratorT  itr,            
        difference_type offset = 0)     
    :
        itr(itr),
        offset(offset)
    {}

    __host__ __device__ __forceinline__ self_type operator++(int)
    {
        self_type retval = *this;
        offset++;
        return retval;
    }

    __host__ __device__ __forceinline__ self_type operator++()
    {
        offset++;
        return *this;
    }

    __host__ __device__ __forceinline__ reference operator*() const
    {
        value_type retval;
        retval.value = itr[offset];
        retval.key = offset;
        return retval;
    }

    template <typename Distance>
    __host__ __device__ __forceinline__ self_type operator+(Distance n) const
    {
        self_type retval(itr, offset + n);
        return retval;
    }

    template <typename Distance>
    __host__ __device__ __forceinline__ self_type& operator+=(Distance n)
    {
        offset += n;
        return *this;
    }

    template <typename Distance>
    __host__ __device__ __forceinline__ self_type operator-(Distance n) const
    {
        self_type retval(itr, offset - n);
        return retval;
    }

    template <typename Distance>
    __host__ __device__ __forceinline__ self_type& operator-=(Distance n)
    {
        offset -= n;
        return *this;
    }

    __host__ __device__ __forceinline__ difference_type operator-(self_type other) const
    {
        return offset - other.offset;
    }

    template <typename Distance>
    __host__ __device__ __forceinline__ reference operator[](Distance n) const
    {
        self_type offset = (*this) + n;
        return *offset;
    }

    __host__ __device__ __forceinline__ pointer operator->()
    {
        return &(*(*this));
    }

    __host__ __device__ __forceinline__ bool operator==(const self_type& rhs)
    {
        return ((itr == rhs.itr) && (offset == rhs.offset));
    }

    __host__ __device__ __forceinline__ bool operator!=(const self_type& rhs)
    {
        return ((itr != rhs.itr) || (offset != rhs.offset));
    }

    __host__ __device__ __forceinline__ void normalize()
    {
        itr += offset;
        offset = 0;
    }

    friend std::ostream& operator<<(std::ostream& os, const self_type& /*itr*/)
    {
        return os;
    }
};


       // end group UtilIterator

}               // CUB namespace
CUB_NS_POSTFIX  // Optional outer namespace(s)